***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Sep. 25, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJP125N06SA-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.248
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=380    VTO=2.68  LEVEL=3  VMAX=5e4 NFS=4e11  GAMMA=0.75)
Rd     d1    d2   2.450e-3    TC=4.6e-3,8u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=66  TBV1=4.9e-4 TBV2=-9e-7  CJO=3.683e-9  M=1.253  VJ=2.693e1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=3.150e-15 N=7.800e-1  RS=4e-8  EG=1.1  TT=20n)
Rdiode  d1  21    4.0e-3 TC=3.0e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.585e-9
.MODEL     DGD    D(CJO=1.585e-9   M=1.379   VJ=6.455)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    4.009e-9
.ENDS PJP125N06SA-AU
*$
